PNP Build: Going Ashore X-Files Retheme

04/06/20

Tags Tabletop Games

Going Ashore TXF Retheme

Going Ashore is a WWII-themed deckbuilder by Felbrigg Herriot that he has described as a spiritual successor to Wipers Salient. Unlike WS, which routinely appears on solitaire game rec lists, Going Ashore has received very little mention on BGG or elsewhere.

I really enjoyed Wipers Salient and quickly became interested in “more of that,” but I also recognized a significant part of my enjoyment of that game stemmed from using Martin’s excellent Mandalorian retheme. I decided to retheme Going Ashore in Nandeck with a X-Files theme. Thematically, I think it works. Instead of invading enemy islands the player is completing 5 series of cases featuring various Monsters of the Week and Mytharc baddies. The player pays to move cards to the investigation phase and, from there, to an action phase where they can be used against the baddies to close cases.

The Build

Laminated 9-card sheets, as usual. I wanted to avoid having an overly dark color scheme, so I kept things minimalist on white cards so I didn’t need to worry too much about gutters or back alignment. I took a lot of design cues from Martin’s Wipers Salient Mandalorian retheme. Instead of creating a mat I designed the trackers and player aids to fit on cards.

The original game tracks enemy hit points with counters. I chose to implement a hit track on each enemy card instead. I also split up the morale track into ones and tens. You can still use counters but I think I prefer using the tracker on each card.

I learned a lot about Nandeck and design working on this project, and I had fun doing it, but boy it was a lot of work. Getting decent images was the tricky part. I wanted to go with illustrations from the comics, because I knew it would look better, but I ended up relying primarily on screenshots. Even though there are 10 seasons of the X-Files and tons of screenshots online it was hard to find good images and filter them in such a way they would print ok on my inkjet. Spray coatings improve inkjet quality substantially in these cases, especially when working with images that have a lot of black, but since I was using laminate the images had to stand for themselves. Having an excellent memory for TXF episodes helped a lot, because when I got the idea for a card I generally knew which episode to go to for an image. If I’d gone with a less-familiar theme I might not have been able to finish this project so quickly.

I am in no hurry to attempt another retheme, certainly not for a game with 100 unique cards, but at this stage I’m confident I can build just about any deck I need to build in Nandeck without much fuss and I could convert any PNP file to a 9-card layout with no trouble. Something like a Herbaceous retheme, which I originally cobbled together as a layered image in Gimp, would be very doable in Nandeck and would probably take less time since it’s easier for me to script, test, adjust than to fiddle with things in a photo editor.

One limitation I discovered is you cannot create image bleeds, images cannot be made to extend beyond the border of the card. You can create solid color bleeds however, and in many cases that will be all you need to create gutters.

Enemy Deck

LINK = enemy-card-data.ods
[all]=1-30
[icon_size] = 35
[icons_xpos] = -1

BORDER=RECTANGLE DPI=300 UNIT=MM PAGE=210,297,PORTRAIT,HV CARDSIZE=63,88 MARGINS=1.5,1.5,1.5,1.5

'Cutting Guides and removing borders BORDER=RECTANGLE,#000000,0.1,MARKDOT,#0000FF FONT=Arial,128,,#000000 EDGE=1,NULL DUPLEX = [all],31 DUPLEX = 32-34,35 PRINT=DUPLEX

IMAGE=[all],"txf-enemy/[image-filename].png",4%,15%,92%,75% FONT=Y-Files,30,FT,#000000,#ffffff roundrect=[all],0%,0%,100%,17%,#FFFFFF,#FFFFFF,1,5 TEXT=[all],[ModifiedTitle],3%,3%,94%,10%,CENTER,WWCENTER

IMAGE=[all],"pistol-gun-black2.png",[icons_xpos],25%,13,13,-15,T FONT=Y-Files,[icon_size],BTFN,#FFFFFF TEXT = [all], [Ammo], [icons_xpos],27%,20%,10%,center, center, 0, 100, 1 FONT=Y-Files,[icon_size],BTFN,#000000 TEXT = [all], [Ammo], [icons_xpos],27%,20%,10%

IMAGE=[all],"police-badge.png",{[icons_xpos]+1.5},45%,10,10,0,T FONT=Y-Files,[icon_size],BTFN,#FFFFFF TEXT = [all], [Shield], [icons_xpos],46%,20%,10%,center, center, 0, 100, 1 FONT=Y-Files,[icon_size],BTFN,#000000 TEXT = [all], [Shield], [icons_xpos],46%,20%,10%

IMAGE=[all],"full-folder2.png",{[icons_xpos]+1.5},62%,10,10,0,T FONT=Y-Files,[icon_size],BTFN,#FFFFFF TEXT = [all], [Hit], [icons_xpos],62%,20%,10%,center, center, 0, 100, 1 FONT=Y-Files,[icon_size],BTFN,#000000 TEXT = [all], [Hit], [icons_xpos],62%,20%,10%

roundrect=[all],0%,82%,100%,20%,#FFFFFF,#FFFFFF,1,5 FONT="Noto Sans",10,TF,#000000 TEXT=[all],[Special],5%,84%,85%,16%,CENTER,WWCENTER FONT="Noto Sans",9,FTI,#000000 TEXT=[all],[Quote],5%,84%,85%,16%,CENTER,WWCENTER

[health_meter_ypos] = 70% [health_meter_xpos]=85% FONT=Y-Files,[icon_size],BTFN,#FFFFFF IF = [Hit] > 1 IMAGE=[all],"circle1.png",[health_meter_xpos],63,9,9,0,T IMAGE=[all],"circle2.png",[health_meter_xpos],54,9,9,0,T ENDIF IF = [Hit] > 2 IMAGE=[all],"circle3.png",[health_meter_xpos],45,9,9,0,T ENDIF IF = [Hit] > 3 IMAGE=[all],"circle4.png",[health_meter_xpos],36,9,9,0,T ENDIF IF = [Hit] > 4 IMAGE=[all],"circle5.png",[health_meter_xpos],27,9,9,0,T ENDIF IF = [Hit] > 5 IMAGE=[all],"circle6.png",[health_meter_xpos],18,9,9,0,T ENDIF

IMAGE=31,"cardback-red-2.png",0,0,100%,100%,0,P IMAGE=32,"aids/case-tracker.png",0,0,100%,100%,0,P IMAGE=33,"aids/player-aid-card.png",0,0,100%,100%,0,P IMAGE=34,"aids/txf-morale-tracker.png",0,0,100%,100%,0,P IMAGE=35,"blankcard.png",0,0,100%,100%,0,P

Agent Deck

LINK = player-card-data.ods
[all]=1-74
[icon_size] = 35
[starting_cards]=1-5
[icons_xpos] = -1
[num_xpos] = -1
[num_ypos] = 15
[num_spacing] = 13

BORDER=RECTANGLE
DPI=300
UNIT=MM
PAGE=210,297,PORTRAIT,HV
CARDSIZE=63,88
MARGINS=1.5,1.5,1.5,1.5

'Cutting Guides and removing borders
BORDER=RECTANGLE,#000000,0.1,MARKDOT,#0000FF
FONT=Arial,128,,#000000
EDGE=1,NULL
DUPLEX = [all],75
PRINT=DUPLEX

IF = [Action]<>[Blank]
IMAGE=[all],"txf-player/[image-filename].png",4%,15%,92%,65%,0,A
ELSE
IMAGE=[all],"txf-player/[image-filename].png",4%,15%,92%,78%,0,A
ENDIF

IF = [Action]<>[Blank]
FONT="Noto Sans",10,TF,#000000
roundrect=[all],0%,75%,100%,25%,#FFFFFF,#FFFFFF,1,5
TEXT=[all],[Action],5%,79%,85%,18%,CENTER,WWCENTER
ELSE
roundrect=[all],0%,90%,100%,10%,#FFFFFF,#FFFFFF,1,5
ENDIF

FONT=Y-Files,30,FT,#000000
roundrect=[all],0%,0%,100%,17%,#FFFFFF,#FFFFFF,1,5
IMAGE=[starting_cards],"small-x-icon.png",1,4,6,6
TEXT=[all],[ModifiedTitle],3%,3%,94%,10%,CENTER,WWCENTER

IMAGE=[all],"red-circle-icon.png",[num_xpos],{[num_ypos]+2},13,13,-15,T
FONT=Y-Files,[icon_size],BTFN,#FFFFFF
TEXT = [all], [Value], [num_xpos],{[num_ypos]+[num_spacing]/3},20%,10%,center, center, 0, 100, 1
FONT=Y-Files,[icon_size],BTFN,#000000
TEXT = [all], [Value], [num_xpos],{[num_ypos]+[num_spacing]/3},20%,10%

IMAGE=[all],"pistol-gun-black2.png",[num_xpos],{[num_ypos]+[num_spacing]},13,13,-15,T
FONT=Y-Files,[icon_size],BTFN,#FFFFFF
TEXT = [all], [Ammo], [num_xpos],{[num_ypos]+[num_spacing]+3},20%,10%,center, center, 0, 100, 1
FONT=Y-Files,[icon_size],BTFN,#000000
TEXT = [all], [Ammo], [num_xpos],{[num_ypos]+[num_spacing]+3},20%,10%

IMAGE=[all],"police-badge.png",{[num_xpos]+1.5},{[num_ypos]+[num_spacing]*2+1},10,10,0,T
FONT=Y-Files,[icon_size],BTFN,#FFFFFF
TEXT = [all], [Shield], {[num_xpos]},{[num_ypos]+[num_spacing]*2+1},20%,10%,center, center, 0, 100, 1
FONT=Y-Files,[icon_size],BTFN,#000000
TEXT = [all], [Shield], {[num_xpos]},{[num_ypos]+[num_spacing]*2+1},20%,10%

IMAGE=[all],"money-stack.png",{[num_xpos]+1},{[num_ypos]+[num_spacing]*3-1},12,12,0,T
FONT=Y-Files,[icon_size],BTFN,#FFFFFF
TEXT = [all], [Worth], [num_xpos],{[num_ypos]+[num_spacing]*3},20%,10%,center, center, 0, 100, 1
FONT=Y-Files,[icon_size],BTFN,#000000
TEXT = [all], [Worth], [num_xpos],{[num_ypos]+[num_spacing]*3},20%,10%

IMAGE=75,"cardback-red-2.png",0,0,100%,100%,0,P

The Game

At first this game didn’t quite click for me, but once I wrapped my brain around the differences between this and Wipers Salient I enjoyed it. It’s a longer, more difficult game with more strategic depth. I never played it with the original theme, but my instinct is it would have been more difficult to get into. As it is now, solving X-Files is fun and I included a few funny cards to help keep the theme light. I’ve since played Wipers Salient again and there is definitely room for both in my collection.